0 sys866:goto10:rem"{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}{del}
    1 c$=c$+" ":k=0:d$=n$
    2 k=k+1:a$=left$(c$,k):ifright$(a$,1)<>" "then2
    3 b$=mid$(c$,k):ifleft$(b$,1)=" "thenk=k+1:goto3
    4 ifb$=""thenn$="***":goto6
    5 b$=left$(b$,len(b$)-1)
    6 a$=left$(a$,len(a$)-1):v$=left$(a$+"***",3)
    7 n$=left$(b$+"***",3):ifn$<>"it*"andn$<>"***"thenreturn
    8 n$=d$:return
   10 poke36879,25:printchr$(8)"{clr}{blk}{swlc}     NOSFERATU":print"{blu}{down}   by M. Taylor.{down}":n$="***"
   15 dimq$(4):q$(1)="N":q$(2)="S":q$(3)="E":q$(4)="W":q$=chr$(34)
   20 l=32:o=45:diml$(l),d$(l),o$(o),c$(o),p(o),f(o)
   30 fori=1too:reado$(i),c$(i),p(i),f(i):next:fori=1tol:readl$(i),d$(i):next:i=1
   35 data"transylvanian Atlas",atl,4,1
   40 data"book of Magic",mag,4,1
   45 data"book of Games",gam,4,1
   50 data"long Rope",rop,8,1
   55 data"brass Key",key,6,1
   60 data"golden Coins",coi,25,1
   65 data"old Lamp",lam,,1
   70 data"balcony Rail",rai,5,
   75 data"newly dug open Grave",gra,10,
   80 data"locked Door",doo,8,
   85 data"wrinkled old Witch",wit,12,
   90 data"Tombstone, engraved:  {blk}BEWARE THE WITCH",sto,10,
   95 data"large red no. 29 Bus",bus,,
  100 data"Hole (above me)",hol,12,
  105 data"bus Conductor",con,13,
  110 data"scarlet Kipper",kip,6,1
  115 data"bottle of Whisky",whi,7,1
  120 data"Water of youth",wat,29,9
  125 data"sharp Axe",axe,14,1
  130 data"inpeneterable Thicket",thi,27,
  135 data"hanging Rope",rop,6,2
  140 data"garden Spade",spa,21,1
  145 data"Hut with locked door",hut,20,
  150 data"oak-Trees",tre,24,
  155 data"brick Wall",wal,26,
  160 data"Sign says: {blk}'TREES ARE RESERVED FOR COFFINS'",sig,24,
  165 data"tall Ladder",lad,15,1
  170 data"Fountain of youth",fou,29,
  175 data"maneating Shark!",sha,16,3
  180 data"brick Wall",wal,28,
  185 data"safety Match",mat,28,1
  190 data"Hole in thicket",hol,29,
  195 data"Sign here says:  {blk}'EXA NA FO TROHS'",sig,27,0
  200 data"Pit in the ground",pit,98,
  205 data"secret Tunnel",tun,30,
  210 data"Stalactites hanging   from the ceiling",sta,31,
  215 data"the count Nosferatu",nos,32,
  220 data"stone Altar",alt,32,
  225 data"giant *BLOODSTONE*",blo,32,1
  230 data"sharp wooden Stick",sti,21,1
  235 data"7-pound Mallet",mal,9,1
  240 data"Crusifix engraved on  the ground",cru,23,
  245 data"stone Sarcophagus",sar,3,
  250 data"decomposing Body",bod,,1
  255 data"wooden Cross",cro,,1
  300 data"in a tall, satin- lined wooden box",000002
  305 datain an empty room,07030501
  310 datain a dark crypt,020004
  315 datain the library,05000003
  320 dataon a balcony over-looking a tall cliff,00040002
  325 dataon a narrow ledge high up a cliff,
  330 datain the kitchen,0802
  335 datain the washroom,000709
  340 datain the mortuary,10000008
  345 datain a desolate windswept graveyard,1109
  350 databy a bus-stop,0010
  355 datain a dark gloomy  cave,
  360 dataon a double-deckerbus,0011
  365 datain a rather dark  yard,15000816
  370 datain a dark shed,0014
  375 databy a fishpond ..,001714
  380 datain a damp swamp,16000018
  385 data"on a track.  To myNorth is a bridge overa pond",19001723
  390 dataon a very flimsy  bridge..,2018
  395 data"on a lawn to the  North of a pond",0019
  400 datain a small hut,0020
  405 datawest of a pond,00230027
  410 datain a sunny field,22241826
  415 datain an oak-forest,23242425
  420 dataat the bottom of adisused cesspit,
  425 datanorth of a rather smelly hole,272523
  430 dataat the top of a   cliff,002622
  435 data"on a narrow ledge,East of a chasm",29
  440 dataat the edge of a  deep chasm,002827
  445 dataat the bottom of adeep hole,
  450 datain a subterranean cavern,0030
  455 datain a cavern where the count sleeps,0031
  700 print"{blu}{down}   press 'RETURN'"
  710 getr$:ifr$<>chr$(13)then710
  720 d=0:if((p(7)<>99andp(7)<>i)orf(7)<>13)andi>30thend=1
  730 ifd=1thenprint"{clr}{blu}It's too dark to see!":goto830
  750 print"{clr}{blu}I'm "l$(i)"."
  760 k=0:forj=1too:ifp(j)=ithenk=1
  770 next:ifk=0then800
  780 print"{blk}Visible items:{down}":forj=1too:ifp(j)=ithenprint"{grn}"o$(j)
  790 next
  800 ifval(d$(i))=0then830
  810 print"{down}{blk}I can go: {red}";:forj=1to4:ifval(mid$(d$(i),j*2-1,2))<>0thenprintq$(j)",";
  820 next:print"{left}."
  830 print"{down}{blu}----------------------";
  831 ifi=19andc>1then988
  832 ifi=32andp(45)<>99andp(37)=ithen9950
  840 iff(43)<0thenf(43)=f(43)+1:iff(43)=0thenprint"I feel weaker."
  841 c$="":input"{down}{blk}Command{red}{rght}{rght}{rght}{CBM-B}{left}{left}{left}";c$:print"{blu}";:ifleft$(c$,3)<>"aga"thengosub1
  842 ifc$="{CBM-B} "thenprint"I don't understand.":goto840
  845 ifn$="the"thene$=v$:c$=b$:gosub1:v$=e$
  846 ifn$="ax*"thenn$="axe"
  850 ifv$="q**"orv$="qui"then9000
  851 k=0:forj=1too:ifc$(j)=n$thenk=j:j=o
  852 next
  855 ifv$="n**"orv$="nor"thenk=1:goto1500
  860 ifv$="s**"orv$="sou"thenk=2:goto1500
  865 ifv$="e**"orv$="eas"thenk=3:goto1500
  870 ifv$="w**"orv$="wes"thenk=4:goto1500
  871 ifv$="i**"orv$="inv"then3000
  873 ifv$="l**"orv$="loo"then720
  874 ifv$="wai"then4500
  876 ifv$="scr"thenb$="Yaaaagh!":goto8500
  877 ifn$="***"thenprint"I need a Noun too!":goto840
  879 ifv$="go*"then1000
  880 ifv$="get"orv$="tak"orv$="g**"then2000
  885 ifv$="dro"orv$="lea"orv$="d**"then2500
  895 ifv$="tie"then3490
  900 ifv$="to*"then3500
  901 ifv$="i=*"theni=val(b$):goto750
  905 ifv$="cli"then4000
  915 ifv$="giv"then5000
  920 ifv$="rea"then5500
  925 ifv$="ope"then6000
  930 ifv$="dri"then6500
  935 ifv$="thr"then6990
  940 ifv$="at*"then7000
  950 ifv$="cho"orv$="cut"then7500
  955 ifv$="lig"then7600
  960 ifv$="dig"then8000
  965 ifv$="say"then8500
  970 print"I don't know "q$a$q$:goto840
  982 print"It shatters!":goto700
  983 print"It's locked!":goto840
  984 print"He doesn't want it.":goto840
  985 print"Nothing happens.":goto840
  987 print"It's not here.":goto840
  988 print"{down}I'm too heavy:{sret}I fall!"
  989 print"{down}{red}I'm dead!{blu}":goto9000
  991 print"I've already done it!":goto840
  992 print"I'm carrying too much.";:goto840
  993 print"I can't "a$:print"a "b$:goto840
  994 print"I don't have it.":goto840
  995 print"I can't do that.":goto840
  996 print"I've already got it.":goto840
  997 print"not now.":goto840
  998 print"I can't go there.":goto840
  999 print"OK.":goto840
 1000 ifn$="hol"then1100
 1005 ifn$="gra"then1130
 1010 ifn$="bus"then1150
 1020 ifn$="pit"then1170
 1030 ifn$="tun"then1190
 1095 v$=n$:goto855
 1100 ifi<>12then997
 1120 i=10:goto720
 1130 ifi<>10then997
 1140 i=12:goto720
 1150 ifi<>p(13)then987
 1160 i=13:goto720
 1170 ifp(34)<>ithen997
 1180 i=30:goto720
 1190 ifi<>30then997
 1200 i=31:goto720
 1500 d$=mid$(d$(i),2*k-1,2):ifval(d$)theni=val(d$):goto720
 1510 ifdthenprint"I fall and break my   neck!":goto989
 1520 goto998
 2000 ifn$="i**"orn$="inv"then3000
 2001 k=0:forj=1too:ifc$(j)=n$thenk=j:j=o
 2005 iff(k)=3thenprint"{down}He doesn't seem to be too keen on that idea:{down}He's eating me!":goto989
 2010 next:iff(k)=2thenprint"It's tied to a rail!":goto840
 2020 ifp(k)=99then996
 2030 ifp(k)<>ithenprint"I can't see it here.":goto840
 2031 ifn$="dus"thenprint"It slips through my   fingers":goto840
 2032 ifk=44thenf(k)=31:o$(k)="pile of Dust":c$(k)="dus":print"It turns to dust!":goto700
 2033 iff(k)=9and(p(17)<>99orf(17)<>4)thenprint"I need a container.":goto840
 2034 ifk=39andp(37)=ithen9950
 2035 iff(k)=0thenprint"That's beyond me!":goto840
 2040 ifc=5then992
 2050 ifk=18theno$(17)="whisky Bottle"
 2060 ifk=17andp(18)=iandf(k)=4thenc=c+1:p(18)=99
 2070 c=c+1:p(k)=99:goto999
 2500 ifp(k)<99then994
 2510 ifk=18andi<>29thenp(k)=98:print"It soaks away.":c=c-1:goto840
 2540 ifi<>12ork<>17orp(18)<>99thenp(k)=i:c=c-1:goto999
 2550 p(18)=98:p(7)=i:p(11)=98:c=c-2:print"{down}The witch drinks the  water, rejuvenates,"
 2560 p(17)=i:print"drops something, and  disappears!":goto700
 3000 print"{down}{blk}I'm carrying:{grn}":k=0:forj=1too:ifp(j)=99thenprinto$(j):k=j
 3010 next:ifk=0thenprint"Nothing at all!"
 3020 goto840
 3490 ifn$<>"rop"then993
 3492 ifp(4)<>99then994
 3495 print"To what? (eg. to key)":goto840
 3500 ifp(4)<>99thenprint"I haven't got a rope.":goto840
 3510 ifn$<>"rai"thena$="tie a rope to":goto993
 3520 ifi<>5then997
 3530 c=c-1:p(4)=5:o$(4)="rope tied to rail":f(4)=2:goto700
 4000 ifk=27then7310
 4005 ifn$<>"rop"then993
 4010 iff(4)<>2or(i<>5andi<>6)then997
 4020 ifc>1then988
 4030 ifi=5theni=6:goto720
 4040 i=5:goto720
 4500 print"time passes...":forj=1to2000:next:ifi<>11orp(13)=11then985
 4510 p(13)=11:print"a bus arrives!":goto700
 5000 ifi<>13then997
 5010 ifp(k)<>99then994
 5015 ifk<>6then984
 5020 print"{down}He takes them, the busstarts, and I'm home"
 5030 print"with";:ifp(39)<99thenprint"out";
 5040 print" Nosferatu's{sret}Bloodstone.":ifp(39)=99thenprint"{grn}* Congratulations *   {blu}You win!
 5050 goto9000
 5500 ifn$="boo"thenprint"Which one?":goto840
 5501 ifn$="lib"thenprint"OK, but it'll take a  while.":forj=1to5000:next
 5502 ifn$="lib"thenprint"{down}That was boring!  It  was in Transylvanian!":goto840
 5509 ifk=0ork>3then993
 5510 ifp(k)<>99then994
 5520 print"The book says:{down}":onkgoto5530,5550,5600
 5530 print"Near the forest is a  disused cess-pit.":goto840
 5550 print"Magic word is:":print"'OVYEZ'":goto840
 5600 print"Bored with this game  already, huh?":goto840
 6000 ifn$="sar"then6100
 6001 ifn$<>"doo"then993
 6005 ifi=20then6040
 6010 ifi<>8orf(10)=2then997
 6020 ifp(5)<>99then983
 6030 f(10)=2:d$(8)="00070914":o$(10)="wide open door":goto700
 6040 ifp(5)<>99then983
 6050 print"My key won't fit!":goto840
 6100 ifi<>p(43)then997
 6105 iff(43)=24then991
 6110 iff(43)>-1thenprint"The lid's too heavy!":goto840
 6120 p(44)=i:f(43)=24:p(45)=i:o$(43)="open Sarcophagus":print"I find something!":goto700
 6500 ifk<>17then993
 6510 ifp(k)<>99then994
 6520 iff(k)=4then991
 6525 f(43)=-6:print"OK.":print"Burp!  It's good!":print"I feel stronger."
 6530 f(k)=4:o$(k)="empty whisky Bottle":c$(k)="bot":goto840
 6990 ifn$<>"axe"then993
 6993 ifp(19)<>99then994
 6996 print"At what? (eg. at bus)":goto840
 7000 ifp(19)<>99thenprint"I need an ax.":goto840
 7010 c=c-1:p(19)=i:ifn$="sta"then7040
 7015 ifn$<>"doo"thenprint"It bounces off.":goto700
 7020 ifi<>20then997
 7030 o$(23)="hut with smashed door":d$(20)="21190000":goto982
 7040 ifi<>31then997
 7050 o$(36)="entrance to cave":d$(31)="3230":goto982
 7310 ifp(k)<>ithen987
 7320 ifi<>25andi<>30then997
 7330 iff(k)=6thenprint"It's broken!":goto840
 7340 ifc<4theni=24:p(27)=i:goto700
 7350 print"I'm too heavy:{sret}The ladder breaks!":f(k)=6:o$(k)="broken Ladder":goto700
 7500 ifp(19)<>99then7000
 7505 ifn$="tre"andi=24thenprint"What's the point?":goto840
 7510 ifk<>20then993
 7520 ifi<>27then997
 7530 iff(k)=8then991
 7540 f(k)=8:o$(k)="mutilated thicket":d$(27)="00262229"
 7550 o$(33)="{blk}'SHORT OF AN AXE'{grn} is  written backwards on  a Sign nearby":goto700
 7600 ifp(31)<>99thenprint"First I need a match.":goto840
 7610 iff(31)=3thenprint"Using a SPENT match?":goto840
 7620 f(31)=3:o$(31)="spent Match":ifk<>7thenprint"It won't burn.":goto840
 7630 ifp(k)<>99then994
 7640 f(k)=13:o$(k)="lit Lamp":print"OK.":goto700
 8000 ifp(22)<>99thenprint"I'll need a spade.":goto840
 8010 ifn$<>"hol"then993
 8020 ifi<>23then997
 8030 ifp(34)=ithen991
 8040 p(42)=98:p(34)=i:goto700
 8500 print"OK.":printq$b$q$:ifp(39)<>iorn$<>"ovy"then985
 8510 print"{down}Nosferatu vanishes in a cloud of smoke!":p(37)=98:goto700
 9000 print"{down}Play again? (Y/N)":poke198,0
 9010 getr$:ifr$="y"thenrun
 9020 ifr$="n"thensys64802
 9030 goto9010
 9950 print"{down}Nosferatu rises from  his altar, and bites  my neck!":goto989